title: ADD INDEX summary: TiDB 数据库中 ADD INDEX 的使用概况。

ADD INDEX

ALTER TABLE.. ADD INDEX 语句用于在已有表中添加一个索引。在 TiDB 中，ADD INDEX 为在线操作，不会阻塞表中的数据读写。

语法图

  1. AlterTableStmt ::=
  2.     'ALTER' IgnoreOptional 'TABLE' TableName ( AlterTableSpecListOpt AlterTablePartitionOpt | 'ANALYZE' 'PARTITION' PartitionNameList ( 'INDEX' IndexNameList )? AnalyzeOptionListOpt )
  4. AlterTableSpec ::=
  5.     TableOptionList
  6. |   'SET' 'TIFLASH' 'REPLICA' LengthNum LocationLabelList
  7. |   'CONVERT' 'TO' CharsetKw ( CharsetName | 'DEFAULT' ) OptCollate
  8. |   'ADD' ( ColumnKeywordOpt IfNotExists ( ColumnDef ColumnPosition | '(' TableElementList ')' ) | Constraint | 'PARTITION' IfNotExists NoWriteToBinLogAliasOpt ( PartitionDefinitionListOpt | 'PARTITIONS' NUM ) )
  9. |   ( ( 'CHECK' | 'TRUNCATE' ) 'PARTITION' | ( 'OPTIMIZE' | 'REPAIR' | 'REBUILD' ) 'PARTITION' NoWriteToBinLogAliasOpt ) AllOrPartitionNameList
  10. |   'COALESCE' 'PARTITION' NoWriteToBinLogAliasOpt NUM
  11. |   'DROP' ( ColumnKeywordOpt IfExists ColumnName RestrictOrCascadeOpt | 'PRIMARY' 'KEY' | 'PARTITION' IfExists PartitionNameList | ( KeyOrIndex IfExists | 'CHECK' ) Identifier | 'FOREIGN' 'KEY' IfExists Symbol )
  12. |   'EXCHANGE' 'PARTITION' Identifier 'WITH' 'TABLE' TableName WithValidationOpt
  13. |   ( 'IMPORT' | 'DISCARD' ) ( 'PARTITION' AllOrPartitionNameList )? 'TABLESPACE'
  14. |   'REORGANIZE' 'PARTITION' NoWriteToBinLogAliasOpt ReorganizePartitionRuleOpt
  15. |   'ORDER' 'BY' AlterOrderItem ( ',' AlterOrderItem )*
  16. |   ( 'DISABLE' | 'ENABLE' ) 'KEYS'
  17. |   ( 'MODIFY' ColumnKeywordOpt IfExists | 'CHANGE' ColumnKeywordOpt IfExists ColumnName ) ColumnDef ColumnPosition
  18. |   'ALTER' ( ColumnKeywordOpt ColumnName ( 'SET' 'DEFAULT' ( SignedLiteral | '(' Expression ')' ) | 'DROP' 'DEFAULT' ) | 'CHECK' Identifier EnforcedOrNot | 'INDEX' Identifier IndexInvisible )
  19. |   'RENAME' ( ( 'COLUMN' | KeyOrIndex ) Identifier 'TO' Identifier | ( 'TO' | '='? | 'AS' ) TableName )
  20. |   LockClause
  21. |   AlgorithmClause
  22. |   'FORCE'
  23. |   ( 'WITH' | 'WITHOUT' ) 'VALIDATION'
  24. |   'SECONDARY_LOAD'
  25. |   'SECONDARY_UNLOAD'
  27. Constraint ::=
  28.     ConstraintKeywordOpt ConstraintElem
  30. ConstraintKeywordOpt ::=
  31.     ( 'CONSTRAINT' Symbol? )?
  33. ConstraintElem ::=
  34.     ( ( 'PRIMARY' 'KEY' | KeyOrIndex IfNotExists | 'UNIQUE' KeyOrIndexOpt ) IndexNameAndTypeOpt | 'FULLTEXT' KeyOrIndexOpt IndexName ) '(' IndexPartSpecificationList ')' IndexOptionList
  35. |   'FOREIGN' 'KEY' IfNotExists IndexName '(' IndexPartSpecificationList ')' ReferDef
  36. |   'CHECK' '(' Expression ')' EnforcedOrNotOpt
  38. IndexNameAndTypeOpt ::=
  39.     IndexName ( 'USING' IndexTypeName )?
  40. |   Identifier 'TYPE' IndexTypeName
  42. IndexPartSpecificationList ::=
  43.     IndexPartSpecification ( ',' IndexPartSpecification )*
  45. IndexPartSpecification ::=
  46.     ( ColumnName OptFieldLen | '(' Expression ')' ) Order
  48. IndexOptionList ::=
  49.     IndexOption*
  51. IndexOption ::=
  52.     'KEY_BLOCK_SIZE' '='? LengthNum
  53. |   IndexType
  54. |   'WITH' 'PARSER' Identifier
  55. |   'COMMENT' stringLit
  56. |   IndexInvisible
  58. KeyOrIndex ::=
  59.     'KEY'
  60. |   'INDEX'
  62. IndexKeyTypeOpt ::=
  63.     ( 'UNIQUE' | 'SPATIAL' | 'FULLTEXT' )?
  65. IndexInvisible ::=
  66.     'VISIBLE'
  67. |   'INVISIBLE'
  69. IndexTypeName ::=
  70.     'BTREE'
  71. |   'HASH'
  72. |   'RTREE'

示例

  1. CREATE TABLE t1 (id INT NOT NULL PRIMARY KEY AUTO_INCREMENT, c1 INT NOT NULL);
  1. Query OK, 0 rows affected (0.11 sec)
  1. INSERT INTO t1 (c1) VALUES (1),(2),(3),(4),(5);
  1. Query OK, 5 rows affected (0.03 sec)
  2. Records: 5  Duplicates: 0  Warnings: 0
  1. EXPLAIN SELECT * FROM t1 WHERE c1 = 3;
  1. +-------------------------+----------+-----------+---------------+--------------------------------+
  2. | id                      | estRows  | task      | access object | operator info                  |
  3. +-------------------------+----------+-----------+---------------+--------------------------------+
  4. | TableReader_7           | 10.00    | root      |               | data:Selection_6               |
  5. | └─Selection_6           | 10.00    | cop[tikv] |               | eq(test.t1.c1, 3)              |
  6. |   └─TableFullScan_5     | 10000.00 | cop[tikv] | table:t1      | keep order:false, stats:pseudo |
  7. +-------------------------+----------+-----------+---------------+--------------------------------+
  8. 3 rows in set (0.00 sec)
  1. ALTER TABLE t1 ADD INDEX (c1);
  1. Query OK, 0 rows affected (0.30 sec)
  1. EXPLAIN SELECT * FROM t1 WHERE c1 = 3;
  1. +------------------------+---------+-----------+------------------------+---------------------------------------------+
  2. | id                     | estRows | task      | access object          | operator info                               |
  3. +------------------------+---------+-----------+------------------------+---------------------------------------------+
  4. | IndexReader_6          | 0.01    | root      |                        | index:IndexRangeScan_5                      |
  5. | └─IndexRangeScan_5     | 0.01    | cop[tikv] | table:t1, index:c1(c1) | range:[3,3], keep order:false, stats:pseudo |
  6. +------------------------+---------+-----------+------------------------+---------------------------------------------+
  7. 2 rows in set (0.00 sec)

MySQL 兼容性

  • 不支持 FULLTEXT，HASH 和 SPATIAL 索引。
  • 不支持降序索引（类似于 MySQL 5.7）。
  • 目前尚不支持在一条中同时添加多个索引。
  • 无法向表中添加 CLUSTERED 类型的 PRIMARY KEY。要了解关于 CLUSTERED 主键的详细信息，请参考聚簇索引。

另请参阅