9 – The Complete Syntax of Lua

Here is the complete syntax of Lua in extended BNF. As usual in extended BNF, {A} means 0 or more As, and [A] means an optional A. (For operator precedences, see §3.4.8; for a description of the terminals Name, Numeral, and LiteralString, see §3.1.)

  2.     chunk ::= block
  4.     block ::= {stat} [retstat]
  6.     stat ::=  ‘;’ | 
  7.          varlist ‘=’ explist | 
  8.          functioncall | 
  9.          label | 
  10.          break | 
  11.          goto Name | 
  12.          do block end | 
  13.          while exp do block end | 
  14.          repeat block until exp | 
  15.          if exp then block {elseif exp then block} [else block] end | 
  16.          for Name ‘=’ exp ‘,’ exp [‘,’ exp] do block end | 
  17.          for namelist in explist do block end | 
  18.          function funcname funcbody | 
  19.          local function Name funcbody | 
  20.          local attnamelist [‘=’ explist] 
  22.     attnamelist ::=  Name attrib {‘,’ Name attrib}
  24.     attrib ::= [‘<’ Name ‘>’]
  26.     retstat ::= return [explist] [‘;’]
  28.     label ::= ‘::’ Name ‘::’
  30.     funcname ::= Name {‘.’ Name} [‘:’ Name]
  32.     varlist ::= var {‘,’ var}
  34.     var ::=  Name | prefixexp ‘[’ exp ‘]’ | prefixexp ‘.’ Name 
  36.     namelist ::= Name {‘,’ Name}
  38.     explist ::= exp {‘,’ exp}
  40.     exp ::=  nil | false | true | Numeral | LiteralString | ‘...’ | functiondef | 
  41.          prefixexp | tableconstructor | exp binop exp | unop exp 
  43.     prefixexp ::= var | functioncall | ‘(’ exp ‘)’
  45.     functioncall ::=  prefixexp args | prefixexp ‘:’ Name args 
  47.     args ::=  ‘(’ [explist] ‘)’ | tableconstructor | LiteralString 
  49.     functiondef ::= function funcbody
  51.     funcbody ::= ‘(’ [parlist] ‘)’ block end
  53.     parlist ::= namelist [‘,’ ‘...’] | ‘...’
  55.     tableconstructor ::= ‘{’ [fieldlist] ‘}’
  57.     fieldlist ::= field {fieldsep field} [fieldsep]
  59.     field ::= ‘[’ exp ‘]’ ‘=’ exp | Name ‘=’ exp | exp
  61.     fieldsep ::= ‘,’ | ‘;’
  63.     binop ::=  ‘+’ | ‘-’ | ‘*’ | ‘/’ | ‘//’ | ‘^’ | ‘%’ | 
  64.          ‘&’ | ‘~’ | ‘|’ | ‘>>’ | ‘<<’ | ‘..’ | 
  65.          ‘<’ | ‘<=’ | ‘>’ | ‘>=’ | ‘==’ | ‘~=’ | 
  66.          and | or
  68.     unop ::= ‘-’ | not | ‘#’ | ‘~’