13.3 bison 示例 2

再来看一个稍微复杂一点的示例，一共有 4 个文件：

词法分析文件： scanner.l

%{
#define YYSTYPE char *
#include "y.tab.h"
int cur_line = 1;
void yyerror(const char *msg);
void unrecognized_char(char c);
%}
 
OPERATOR        [-/+*()=;]
INTEGER         [0-9]+
IDENTIFIER      [_a-zA-Z][_a-zA-Z0-9]*
WHITESPACE      [ \t]*
 
%%
{OPERATOR}      { return yytext[0]; }
{INTEGER}       { yylval = strdup(yytext); return T_IntConstant; }
{IDENTIFIER}    { yylval = strdup(yytext); return T_Identifier; }
{WHITESPACE}    { /* ignore every whitespcace */ }
\n              { cur_line++; }
.               { unrecognized_char(yytext[0]); }
%%
 
int yywrap(void) { 
    return 1;
}
 
void unrecognized_char(char c) {
    char buf[32] = "Unrecognized character: ?";
    buf[24] = c;
    yyerror(buf);
}
 
void yyerror(const char *msg) {
    printf("Error at line %d:\n\t%s\n", cur_line, msg);
    exit(1);
}

语法分析文件： parser.y

%{
#include <stdio.h>
#include <stdlib.h>
void yyerror(const char*);
#define YYSTYPE char *
%}
 
%token T_IntConstant T_Identifier
 
%left '+' '-'
%left '*' '/'
%right U_neg
 
%%
 
S   :   Stmt
    |   S Stmt
    ;
 
Stmt:   T_Identifier '=' E ';'  { printf("pop %s\n\n", $1); }
    ;
 
E   :   E '+' E                 { printf("add\n"); }
    |   E '-' E                 { printf("sub\n"); }
    |   E '*' E                 { printf("mul\n"); }
    |   E '/' E                 { printf("div\n"); }
    |   '-' E %prec U_neg       { printf("neg\n"); }
    |   T_IntConstant           { printf("push %s\n", $1); }
    |   T_Identifier            { printf("push %s\n", $1); }
    |   '(' E ')'               { /* empty */ }
    ;
 
%%
 
int main() {
    return yyparse();
}

makefile 文件： makefile

CC = gcc
OUT = tcc
OBJ = lex.yy.o y.tab.o
SCANNER = scanner.l
PARSER = parser.y
 
build: $(OUT)
 
run: $(OUT)
    ./$(OUT) < test.c > test.asm
 
clean:
    rm -f *.o lex.yy.c y.tab.c y.tab.h y.output $(OUT)
 
$(OUT): $(OBJ)
    $(CC) -o $(OUT) $(OBJ)
 
lex.yy.c: $(SCANNER) y.tab.c
    flex $<
 
y.tab.c: $(PARSER)
    bison -vdty $<

测试文件： test.c

a = 1 + 2 * ( 2 + 2 );
b = c + d;
e = f + 7 * 8 / 9;

这个示例对第一个示例进行了一些扩充。

词法分析文件中：

增加了 T_Identifier 类型的 token ，整数类型的 token 名改为了 T_IntConstant ；

增加了一个全局变量 cur_line ，表示扫描所在的位置（行）；

增加了错误处理函数 unrecognized_char 和 yyerror 函数，前者在扫描到非法字符时被执行，并将相关信息传递给后者，后者则打印出错误信息以及当前位置，并退出程序；

第二行增加了 define YYSTYPE char ，上一节中说过了，全局变量 yylval 的类型是 YYSTYPE ，而 YYSTYPE 默认为 int ，添加了这一行后， YYSTYPE 变成了 char ，这样 yylval 的类型就变成了 char 了；

当扫描到完整的整数或标识符时， yylval = strdup(yytext) 被执行，扫描到的字符串被拷贝一份传给了 yylval ，到语法分析时，这个字符串将被绑定到终结符 T_IntConstant 或 T_Identifier 上面。

语法分析文件中：

语法规则有所扩充，增加了终结符 T_Identifier 和非终结符 Stmt ， Stmt 可表示一个赋值表达式；

符号优先级那一段，增加了 %left U_neg ，表示增加一个符号，该符号为左结合，且优先级在 和 / 之上，这个符号在 ‘-‘ E %prec U_neg 那一行被使用，%prec 命令可以给一个产生式定义一个优先级，”%prec U_neg” 表示这个产生式的优先级和 U_neg 一样（而不是等于产生式中最右边的、定义了优先级的符号的优先级），当出现 shift/reduce 冲突时，将利用 U_neg 的优先级和 lookahead 的优先级比较，然后根据比较结果来选择动作；

大部分产生式的后面的 action 都是执行一个 printf 函数，表示这些产生式被 reduce 时所打印的字符串。

makefile 里面是编译这个程序的命令，在终端输入 make 后，将编译生成可执行文件 tcc ，然后用 test.c 文件来测试一下：

./tcc < test.c > test.asm

test.asm 文件中的输出内容如下：

push 1
push 2
push 2
push 2
add
mul
add
pop a
 
push c
push d
add
pop b
 
push f
push 7
push 8
mul
push 9
div
add
pop e

可以看出 test.c 文件里的所有赋值表达式都被转换成相应的 Pcode 了，是不是很神奇？这个程序相当于我们的 TinyC 前端的一个雏形了。在这个雏形前端中请注意源文件的解析过程中各产生式折叠的先后顺序，中间代码就是按照产生式折叠的顺序生成的。

第 13 章完