Calling C from V

Example

  1. #flag -lsqlite3
  2. #include "sqlite3.h"
  3. // See also the example from https://www.sqlite.org/quickstart.html
  4. struct C.sqlite3 {
  5. }
  7. struct C.sqlite3_stmt {
  8. }
  10. type FnSqlite3Callback = fn (voidptr, int, &&char, &&char) int
  12. fn C.sqlite3_open(&char, &&C.sqlite3) int
  14. fn C.sqlite3_close(&C.sqlite3) int
  16. fn C.sqlite3_column_int(stmt &C.sqlite3_stmt, n int) int
  18. // ... you can also just define the type of parameter and leave out the C. prefix
  19. fn C.sqlite3_prepare_v2(&C.sqlite3, &char, int, &&C.sqlite3_stmt, &&char) int
  21. fn C.sqlite3_step(&C.sqlite3_stmt)
  23. fn C.sqlite3_finalize(&C.sqlite3_stmt)
  25. fn C.sqlite3_exec(db &C.sqlite3, sql &char, cb FnSqlite3Callback, cb_arg voidptr, emsg &&char) int
  27. fn C.sqlite3_free(voidptr)
  29. fn my_callback(arg voidptr, howmany int, cvalues &&char, cnames &&char) int {
  30.     unsafe {
  31.         for i in 0 .. howmany {
  32.             print('| ${cstring_to_vstring(cnames[i])}: ${cstring_to_vstring(cvalues[i]):20} ')
  33.         }
  34.     }
  35.     println('|')
  36.     return 0
  37. }
  39. fn main() {
  40.     db := &C.sqlite3(0) // this means `sqlite3* db = 0`
  41.     // passing a string literal to a C function call results in a C string, not a V string
  42.     C.sqlite3_open(c'users.db', &db)
  43.     // C.sqlite3_open(db_path.str, &db)
  44.     query := 'select count(*) from users'
  45.     stmt := &C.sqlite3_stmt(0)
  46.     // NB: you can also use the `.str` field of a V string,
  47.     // to get its C style zero terminated representation
  48.     C.sqlite3_prepare_v2(db, &char(query.str), -1, &stmt, 0)
  49.     C.sqlite3_step(stmt)
  50.     nr_users := C.sqlite3_column_int(stmt, 0)
  51.     C.sqlite3_finalize(stmt)
  52.     println('There are $nr_users users in the database.')
  53.     //
  54.     error_msg := &char(0)
  55.     query_all_users := 'select * from users'
  56.     rc := C.sqlite3_exec(db, &char(query_all_users.str), my_callback, voidptr(7), &error_msg)
  57.     if rc != C.SQLITE_OK {
  58.         eprintln(unsafe { cstring_to_vstring(error_msg) })
  59.         C.sqlite3_free(error_msg)
  60.     }
  61.     C.sqlite3_close(db)
  62. }