包由包定义（PACKAGE）和包主体（PACKAGE BODY）两个部分组成：

• 包定义（PACKAGE）：包定义部分声明包内数据类型、变量、常量、游标、子程序和异常错误处理等元素，这些元素为包的公有元素。

• 包主体（PACKAGE BODY）：包主体则是包定义部分的具体实现，它定义了包定义部分所声明的游标和程序，在包主体中还可以声明包的私有元素。

包定义和包主体分开编译，并作为两部分分开的对象存放在数据库字典中，详见数据字典 user_source, all_source, dba_source。

创建包

创建包定义的语法如下：

CREATE [OR REPLACE] PACKAGE package_name
[AUTHID {CURRENT_USER | DEFINER}]
{IS | AS}
[公有数据类型定义[公有数据类型定义]…]
[公有游标声明[公有游标声明]…]
[公有变量、常量声明[公有变量、常量声明]…]
[公有子程序声明[公有子程序声明]…]
END [package_name];

其中，AUTHID CURRENT_USER 和 AUTHID DEFINER 选项说明应用程序在调用函数时所使用的权限模式。

创建包体定义的语法如下：

CREATE [OR REPLACE] PACKAGE BODY package_name
{IS | AS}
[私有数据类型定义[私有数据类型定义]…]
[私有变量、常量声明[私有变量、常量声明]…]
[私有子程序声明和定义[私有子程序声明和定义]…]
[公有游标定义[公有游标定义]…]
[公有子程序定义[公有子程序定义]…]
BEGIN
PL/SQL 语句
END [package_name];

示例

如下例所示，创建的包名称为 demo_pack, 该包中包含一个记录变量 DeptRec、两个函数和一个过程。

CREATE OR REPLACE PACKAGE demo_pack
IS
    DeptRec DEPARTMENTS%ROWTYPE;
    FUNCTION add_dept(dept_no NUMBER, dept_name VARCHAR2, location VARCHAR2)
      RETURN NUMBER;
    FUNCTION remove_dept(dept_no NUMBER)
        RETURN NUMBER;
    PROCEDURE query_dept(dept_no IN NUMBER);
END demo_pack;

包主体的创建方法，它实现上面所声明的包定义，并在包主体中声明一个私有变量 flag 和一个私有函数 check_dept，由于在 add_dept 和 remove_dept 等函数中需要调用 check_dpet 函数，所以，在定义 check_dept 函数之前首先对该函数进行声明，这种声明方法称作前向声明。

CREATE OR REPLACE PACKAGE BODY demo_pack
    IS 
FUNCTION add_dept
(dept_no NUMBER, dept_name VARCHAR2, location VARCHAR2)
    RETURN NUMBER
    IS 
    empno_remaining EXCEPTION;
       PRAGMA EXCEPTION_INIT(empno_remaining, -1);
   /* -1 是违反唯一约束条件的错误代码 */
BEGIN
    INSERT INTO dept VALUES(dept_no, dept_name, location);
    IF SQL%FOUND THEN
        RETURN 1;
    END IF;
EXCEPTION
       WHEN empno_remaining THEN 
        RETURN 0;
    WHEN OTHERS THEN
        RETURN -1;
END add_dept;
FUNCTION remove_dept(dept_no NUMBER)
    RETURN NUMBER
    IS 
BEGIN
    DELETE FROM dept WHERE deptno=dept_no;
   IF SQL%FOUND THEN
        RETURN 1;
    ELSE
        RETURN 0;
   END IF;
EXCEPTION
WHEN OTHERS THEN
        RETURN -1;
END remove_dept;
PROCEDURE query_dept
(dept_no IN NUMBER)
    IS
BEGIN
SELECT * INTO DeptRec FROM dept WHERE deptno=dept_no;
EXCEPTION
       WHEN NO_DATA_FOUND THEN  
          DBMS_OUTPUT.PUT_LINE('数据库中没有编码为'||dept_no||'的部门');
       WHEN TOO_MANY_ROWS THEN
          DBMS_OUTPUT.PUT_LINE('程序运行错误!');
       WHEN OTHERS THEN
           DBMS_OUTPUT.PUT_LINE(SQLCODE||'----'||SQLERRM);
END query_dept;
BEGIN 
    Null;
END demo_pack;

调用包的函数和方法

调用包里面的变量、常量、函数、方法等需要在对象名里包含包的名字，并用“.”分隔。即对包内共有元素的调用格式为：包名.元素名称。

调用 demo_pack 包内函数对 dept 表进行插入、查询和修改操作，并通过 demo_pack 包中的记录变量 DeptRec 显示所查询到的数据库信息，如下例所示：

obclient> DECLARE
    ->     Var NUMBER;
    -> BEGIN
    ->     Var := demo_pack.add_dept(900,'Administration', 'Beijing');
    ->     IF var =-1 THEN
    ->         DBMS_OUTPUT.PUT_LINE(SQLCODE||'----'||SQLERRM);
    ->     ELSIF var =0 THEN
    ->         DBMS_OUTPUT.PUT_LINE('该部门记录已经存在！');
    ->     ELSE
    ->         DBMS_OUTPUT.PUT_LINE('添加记录成功！');
    ->         Demo_pack.query_dept(900);
    ->         DBMS_OUTPUT.PUT_LINE(demo_pack.DeptRec.deptno||'---'||demo_pack.DeptRec.dname||'---'||demo_pack.DeptRec.loc);
    ->         var := demo_pack.remove_dept(900);
    ->         IF var =-1 THEN
    ->             DBMS_OUTPUT.PUT_LINE(SQLCODE||'----'||SQLERRM);
    ->         ELSIF var=0 THEN
    ->             DBMS_OUTPUT.PUT_LINE('该部门记录不存在！');
    ->         ELSE
    ->             DBMS_OUTPUT.PUT_LINE('删除记录成功！');
    ->         END IF;
    ->     END IF;
    -> END;
    -> /
Query OK, 0 rows affected (0.65 sec)
添加记录成功！
900---Administration---Beijing
删除记录成功！